<%
'-----------------------------------------------------
'Funcao: ManutencaoTabelas(ByVal Cmd)
'Sinopse: Realiza manutenção das tabelas de um banco mySQL
'Parametro(s):
'	Cmd: Comando a ser executado. Os comandos podem ser:
'		'ANALYZE'
'		'CHECK'	
'		'OPTIMIZE' 
'		'REPAIR' 
'Retorno: String
'Autor: Gabriel Fróes
'Site: www.codigofonte.com.br
'-----------------------------------------------------
Function ManutencaoTabelas(ByVal Cmd)
	'Declarações
	Dim strRetorno
	Dim strSQL
	Dim objRS
	Dim objRS2
	Dim objConexao
	Dim strConexao
		
	'Inicialização
	Set objConexao	= Server.CreateObject("ADODB.Connection")
	Set objRS		= Server.CreateObject("ADODB.RecordSet")
	Set objRS2		= Server.CreateObject("ADODB.RecordSet")
	strRetorno		= ""
	strConexao		= "SUA CONEXAO COM O BANCO MYSQL"
		
	'Lista das tabelas
	objConexao.Open strConexao
	Set objRS = objConexao.Execute("SHOW TABLES")
	strRetorno = "<table border=1>"
	strRetorno = strRetorno & "<tr>"
	strRetorno = strRetorno & "	<th>Tabela</th>"
	strRetorno = strRetorno & "	<th>Operação</th>"
	strRetorno = strRetorno & "	<th>Tipo</th>"
	strRetorno = strRetorno & "	<th>Mensagem</th>"
	strRetorno = strRetorno & "</tr>"
	If Not objRS.EOF Then
		Do While Not objRS.EOF
			strSQL = Cmd & " TABLE " & objRS.Fields(0).Value & ""
			Set objRS2 = objConexao.Execute(strSQL)
			If Not objRS2.EOF Then
				strRetorno = strRetorno & "<tr>"
				strRetorno = strRetorno & "	<td>" & objRS2("TABLE")		& "</td>"
				strRetorno = strRetorno & "	<td>" & objRS2("OP")		& "</td>"
				strRetorno = strRetorno & "	<td>" & objRS2("MSG_TYPE")	& "</td>"
				strRetorno = strRetorno & "	<td>" & objRS2("MSG_TEXT")	& "</td>"
				strRetorno = strRetorno & "</tr>"
			End If
			objRS2.Close
			objRS.MoveNext
		Loop
	Else
		strRetorno = strRetorno & "<tr><td colspan=4>Não foram encontrads tabelas</td></tr>"
	End If
	strRetorno = strRetorno & "</table>"
	objRS.Close

	'Retornando a função
	ManutencaoTabelas = strRetorno
		
	'Destruição
	Set objRS2		= Nothing
	Set objRS		= Nothing
	Set objConexao	= Nothing	
End Function
%>