<%
'=======================================================
'Nome: getEnviromentVariable(ByVal Variavel, ByVal TipoEV)
'Tipo: Funcao
'Sinopse: Retorna o valor de uma Variável de Ambiente 
'          do Servidor de acordo com o tipo
'Parametros:Variavel: Nome da variável de ambiente
'            TipoEV: Tipo de variável de ambiente, pode 
'                    ser: SYSTEM ou PROCESS, o default é
'                    SYSTEM
'Retorno: String
'Autor: Gabriel Fróes - www.codigofonte.com.br
'=======================================================
Function getEnviromentVariable(ByVal Variavel, ByVal TipoEV)
    'Declarando variáveis
    Dim ValorVariavel
    Dim objVariavel
    
    'Verificando se foi passado o tipo
    TipoEV = Ucase(Trim(TipoEV))
    If TipoEV <> "PROCESS" Then
        TipoEV = "SYSTEM"
    End If
    
    'Criação de objetos
    Set objWSShell    = Server.CreateObject("WScript.Shell")
    
    'Pegando a variável de ambiente
    Set objVariavel    = objWSShell.Environment(TipoEV)
    ValorVariavel    = objVariavel(Variavel)
    
    'Retornando a função
    getEnviromentVariable = ValorVariavel
    
    'Destruindo os objetos
    Set objVariavel = Nothing
    Set objWSShell    = Nothing
End Function
%>

<%
'Exemplo de Utilização
Response.Write "WINDIR: " & getEnviromentVariable("WINDIR", "PROCESS")
%>